Collecting Sensor Data

Get started with:

and

Don't see your favorite hardware here? Rest assured the Notecard works with virtually every MCU and SBC available. If you can't figure out how to complete this tutorial let us know in our forum and we can help you out.

Introduction

This tutorial should take approximately 40-50 minutes to complete.

In this tutorial, you'll learn how to take sensor readings from a Device and send readings to your Notecard and the Blues Notehub. You'll use C/C++ (Arduino/Wiring) running on a Adafruit HUZZAH32 wired up to Notecarrier-F hardware. If you would like to use a different language, board, or Notecarrier, modify the dropdowns at the top of this guide.

The tutorial uses mock sensor readings for simplicity, but feel free to hook up a physical sensor of your choice and use that instead.

note

If you get stuck at any point during this tutorial, the full source for each example is available on GitHub:

View this example's source code on GitHub.

Set up Hardware

First, you'll need to get all of your hardware connected. Follow the instructions below to connect your Adafruit HUZZAH32 and Notecard mounted on a Notecarrier-F.

In order to complete this guide, you'll need the following:

Notecard mounted to Notecarrier-F.

Any ESP32-compatible Microcontroller (MCU). We'll be using the Adafruit HUZZAH32, but any MCU that can be programmed with the Arduino IDE will do.

Micro USB to USB-A cable.

Connect the sensor and MCU to the Notecarrier

Plug your Feather-compatible Adafruit HUZZAH32 device into the Feather headers on the Notecarrier-F.
Plug the USB cable directly into your Feather-compatible Adafruit HUZZAH32, which will allow you to flash firmware to your device.

Create a Notehub Project

Now that your hardware is all connected, let's create a new Notehub project to receive sensor readings from your Notecard.

Navigate to notehub.io and log-in, or create a new account.
Using the New Project card, give your project a name and ProductUID.

NOTE: The ProductUID must be globally unique, so we recommend a namespaced name like "com.your-company.your-name:your_product".

Take note of your ProductUID. This identifier is used by Notehub to associate your Notecard to your project.

Write Firmware

Configure the Arduino IDE

For this portion of the guide, we'll be using the Arduino IDE, so be sure to install version 2.0+ if you haven't already.

Once installed, we'll need to add support for your Adafruit HUZZAH32 Board.

Configure the Arduino Boards Manager to use the ESP32

Start the Arduino IDE and open the Preferences menu.
Copy the following path https://raw.githubusercontent.com/espressif/arduino-esp32/gh-pages/package_esp32_index.json into the "Additional Board Manager URLs" field. If there's already something in the box, then add a comma to separate the URLs.
Click OK, then open the Boards Manager from the Tools > Board: [board name] > Boards Manager... menu.
Search for "esp32" and click the Install button to add ESP32 board support to the Arduino IDE.
Once the installation is complete, click the Close button.
To proceed, you may need to install the SiLabs CP2104 driver. This driver allows the Arduino IDE to communicate with (and flash) your ESP32 DevKit over USB.
- macOS Big Sur (and later): The necessary driver is already installed.
- Earlier versions of macOS: Download and install "CP210x VCP Mac OSX Driver" from SiLabs.
- Windows 10: Download and install "CP210x Universal Windows Driver" from SiLabs.
- Windows 7 to 8.1: Download and install the "CP210x Windows Drivers" from SiLabs.
- Linux: Download and install the appropriate CP210x driver for your Linux kernel from SiLabs.
Linux note: If your kernel version is >= 5, you do not need to install the driver. If you are unsure, you can check your kernel version by running uname -srm from your terminal application.
Next, plug your Arduino device back in, open the Arduino IDE, select Adafruit ESP32 Feather from the Tools > Board menu, and select the appropriate Port for your device.

Additional Linux Setup

In order to support the Adafruit HUZZAH32, you will need to install the following packages:

sudo apt update && sudo apt install \
  python-is-python3 \
  python3-serial

warning

The Arduino IDE MUST NOT be installed from the Ubuntu store. Instead, it must be installed from the ZIP file downloaded from the Arduino downloads page._

Great job, now you're ready to write some firmware!

Communicating With Your Notecard

When communicating with the Notecard over I2C, you'll want to use the note-arduino library. The code snippets below provide everything you need to talk to the Notecard over I2C in Arduino.

warning

The Notecarrier-F provides only an I2C connection between a Feather MCU host and the Notecard; it does not facilitate Serial communication between devices.

Install the Notecard Arduino Library

To use the note-arduino library, you'll need to add it to the Arduino IDE.
Click on Tools > Manage Libraries...
Search for "Blues" in the input box and click the "Install" button next to the "Blues Wireless Notecard" result.
Create a new sketch and select the Sketch > Include Library > Contributed Libraries > Blues Wireless Notecard menu option, to add the following include to your sketch:
```
#include <Notecard.h>
```

Set Up Your Notecard

Now, configure a Serial interface. Serial will be used to log information to the Serial terminal of the Arduino IDE.
```
#define usbSerial Serial
```

Next, add a definition for your ProductUID using the value you specified when creating your Notehub project.


#define productUID "com.your-company.your-name:your_product"

Above the setup() and loop() functions, declare a global object to represent the Notecard.
```
Notecard notecard;
```
In the setup() function, initialize the usbSerial object and tell the Notecard library to use this serial object for sending debug output.
```
delay(2500);
usbSerial.begin(115200);
```
Initialize an instance of the Notecard class and initialize an I2C connection to the Notecard using the notecard.begin() function. Then, use setDebugOutputStream() to link the debug output to usbSerial with the following code:
```
notecard.begin();
notecard.setDebugOutputStream(usbSerial);
```

Now, we'll configure the Notecard. Using the hub.set request, we associate this Notecard with the ProductUID of your project and set the Notecard to operate in continuous mode, which indicates that the device should immediately make a connection to Notehub and keep it active.


J *req = notecard.newRequest("hub.set");
JAddStringToObject(req, "product", productUID);
JAddStringToObject(req, "mode", "continuous");
notecard.sendRequest(req);

The lines above build-up a JSON object by adding two string values for product and mode, and then fires the request off to the Notecard with the sendRequest() function.

Flash Your Firmware

Click the Upload button (right arrow icon) to flash firmware to your device.

View the Serial Log

Now that your firmware is running on your device, you can use a Serial Monitor to view device output. Complete the instructions below in your preferred IDE.

Open the Arduino Serial Monitor. If everything has been connected and configured properly, you'll see a few debug messages, including the JSON object you sent, as well as the response from the Notecard {}.

Read from the sensor

Now that you've configured your Arduino to communicate with the Notecard, let's grab some pseudo sensor readings.

note

If you have your own sensor, feel free to hook it up and use your own values instead of this tutorial's mocked ones.

Install the NotecardPseudoSensor Library

To generate mock sensor readings you'll use the NotecardPseudoSensor library. To add the library to Arduino IDE start by clicking on Tools > Manage Libraries...
Search for “NotecardPseudoSensor” in the input box and click the Install button next to the “Blues Wireless Notecard Pseudo Sensor” result.

Gather Sensor Readings

Add the following include to the top of your sketch:


#include <NotecardPseudoSensor.h>

Next, include the following namespace under your includes.


using namespace blues;

After that, create an instance of NotecardPseudoSensor with the line of code below. Place this directly under your existing Notecard notecard statement.
```
NotecardPseudoSensor sensor(notecard);
```

Finally, place the following code in your loop function, which generates mock temperature and humidity readings, prints them to the console, and then waits 15 seconds before exiting the loop.


float temperature = sensor.temp();
float humidity = sensor.humidity();

usbSerial.print("Temperature = ");
usbSerial.print(temperature);
usbSerial.println(" *C");
usbSerial.print("Humidity = ");
usbSerial.print(humidity);
usbSerial.println(" %");

delay(15000);

Upload this code to your Adafruit HUZZAH32. Open the Serial Monitor and you'll see temperature and humidity readings every 15 seconds.

Send Sensor Readings to the Notecard

Now that we're getting sensor readings, let's send these to our Notecard.

To send a sensor reading to the Notecard, we'll need to construct a new JSON request to the note.add API that includes a new Notefile name (sensors.qo), sets the sync field to true to instruct the Notecard to sync to Notehub immediately, and finally, sets the body to the sensor temperature and humidity. Add the following in loop right after the usbSerial commands to print out readings.


J *req = notecard.newRequest("note.add");
if (req != NULL)
{
  JAddStringToObject(req, "file", "sensors.qo");
  JAddBoolToObject(req, "sync", true);
  J *body = JAddObjectToObject(req, "body");
  if (body)
  {
    JAddNumberToObject(body, "temp", temperature);
    JAddNumberToObject(body, "humidity", humidity);
  }
  notecard.sendRequest(req);
}

Upload this code to your device. After reboot, the Serial monitor will update to display the response from the note.add request (the total number of Notes in the notefile) each time you add a new reading.

note

Concerned about the size of note-arduino? You can communicate with the Notecard without using the library.

View Data in Notehub

Once you start capturing readings, your Notecard will initiate a connection to Notehub and will start transferring Notes. Depending on signal strength and coverage in your area, it may take a few minutes for your Notecard to connect to Notehub and transfer data.

Return to notehub.io and open your project. You should see your notecard in the Devices view.
Now, click on the Events left menu item. Once your sensor Notes start syncing, they'll show up here.

Use Environment Variables

Environment variables are a Notehub state and settings management feature that allow you to set variables in key-value pairs, and intelligently synchronize those values across devices and fleets of devices.

In this section you'll learn how environment variables work by creating a variable that determines how often your firmware should take sensor readings.

Setting an Environment Variable

Environment variables can be set in the Notehub UI or through the Notehub API. In this tutorial you'll learn how to set the values through the Notehub UI. If you'd like to instead set environment variables through the Notehub API, refer to the Environment Variable API.

Return to your Notehub project, go the the Devices page, and double click your device. You should see a screen that looks like this.
Click the Environment tab.
Under the Device environment variables header, define a new environment variable named reading_interval and set its value to 30.

Now that you have an environment variable set you're ready to use it in your app. Let's look at how that works.

Using Environment Variables in Firmware

The Notecard provides a set of requests for working with environment variables. The most common of these requests is env.get, which allows you to retrieve the value of an environment variable.

Complete the steps below to use the env.get request to retrieve and use the reading_interval environment variable you set in Notehub.

Place the following new function at the bottom of your sketch.


// This function assumes you’ll set the reading_interval environment variable to
// a positive integer. If the variable is not set, set to 0, or set to an invalid
// type, this function returns a default value of 60.
int getSensorInterval() {
  int sensorIntervalSeconds = 60;
  J *req = notecard.newRequest("env.get");
  if (req != NULL) {
      JAddStringToObject(req, "name", "reading_interval");
      J* rsp = notecard.requestAndResponse(req);
      int readingIntervalEnvVar = atoi(JGetString(rsp, "text"));
      if (readingIntervalEnvVar > 0) {
        sensorIntervalSeconds = readingIntervalEnvVar;
      }
      notecard.deleteResponse(rsp);
  }
  return sensorIntervalSeconds;
}

Next, find the delay(15000) line at the bottom of your loop() function, and replace it with the code below.


int sensorIntervalSeconds = getSensorInterval();
serialDebug.print("Delaying ");
serialDebug.print(sensorIntervalSeconds);
serialDebug.println(" seconds");
delay(sensorIntervalSeconds * 1000);

Finally, back in setup(), adjust your existing hub.set configuration to set the sync argument to true. When sync is true, the Notecard synchronizes inbound environment variable changes as soon as they're made in Notehub.


J *req = notecard.newRequest("hub.set");
JAddStringToObject(req, "product", productUID);
JAddStringToObject(req, "mode", "continuous");
JAddBoolToObject(req, "sync", true); // ADD THIS LINE
notecard.sendRequest(req);

With this code in place, your firmware now uses the reading_interval environment variable to determine how many seconds to delay in between sensor readings. If you flash this updated code to your device and open your serial monitor, you can see the device retrieving and using the reading_interval: 30 value you set in Notehub.

And with that, you've used your first environment variable on your Notecard! To see the real power of environment variables in action, try returning to Notehub and updating your device's reading_interval with your serial monitor open. Your firmware will retrieve the updated value and start using it immediately.

note

This tutorial had you use several configuration settings are best used when you have your Notecard connected to mains power.

In the hub.set request, setting mode to "continuous" tells the Notecard to maintain an active network connection.
In the hub.set request, setting sync to true tells the Notecard to immediately synchronize inbound Notes and environment variables from Notehub.
In the note.add request, setting sync to true tells the Notecard to immediately synchronize all outbound Notes to Notehub.

Because each of these settings cause the Notecard to use more power, you may wish to disable them if you plan to transition your project to battery power. You can run the command below to put your Notecard into periodic mode with the sync argument turned off.

{
 "req": "hub.set",
 "mode": "periodic",
 "sync": false,
 "outbound": 60,
 "inbound": 120
}

Learn more about optimizing the Notecard for low-power scenarios in Low Power Design.

Next Steps

Congratulations! You've successfully connected your Adafruit HUZZAH32 to your Notecard and built a basic IoT project.

If you're following the Blues Quickstart, next we recommend learning how to send (and visualize) your data in a cloud application:

~~Use the Notecard to Send Data~~
~~Set Up Your Microcontroller~~
~~Build Your First IoT App With Blues~~
Send Data to Your Cloud

At any time, if you find yourself stuck, please reach out on the community forum.